#!/usr/local/bin/gnuplot-v4.4.3
#OR #!/usr/bin/gnuplot
set terminal postscript color dashed enhanced portrait 'Bold-Times-Roman'
#If you specify a font size above, the font may not work on some computers.
set encoding iso_8859_1 #Enables symbols, like Angstroms

set size 0.80,0.40 #Feel free to change the y-size, but leave x-size <1
set output 'multiplot.eps'


#FOR CUSTOM LINESTYLES
set style line 1 lt 2 lw 3 lc rgb "red"
set style line 2 lt 3 lw 3 lc rgb "dark-green"
set style line 3 lt 4 lw 3 lc rgb "blue"
set style line 4 lt 5 lw 3 lc rgb "orange"
set style line 5 lt 6 lw 3 lc rgb "dark-magenta"


#FOR PLOTTING FITS:
#plot 'file.dat' every 3 lt 3 pt 2 lw 2 with points



###FOR PLOTTING MULTIPLE GRAPHS:
set multiplot
set tmargin 1
set bmargin 2
set rmargin 2
set lmargin 8
set size 0.8, 0.20

set key samplen 1.5

set ytics 0.5
set mytics 2
set xtics 2
set mxtics 2

#Top Plot
set label 1 "a)" at -3.7,0.7 font "Bold-Times-Roman,20"
set origin 0.0,0.19
set format x "" #Removes all numbers from the x-axis
set ylabel "FFT[k{/Symbol c}(k)]" offset 1,0 font "Bold-Times-Roman,18"

set xrange[-4:4]

plot \
-sin(x) title '-Sin (x)' ls 1,\
cos(x) title 'Cos (x)' ls 2

#Bottom Plot
set origin 0.0,0.03
set format x
set xlabel "r ({\305})" offset 0,0.0 font "Bold-Times-Roman,18"
set ylabel "FFT[k{/Symbol c}(k)]" offset -0.4,0 font "Bold-Times-Roman,18"
unset label 1
set label 1 "b)" at -3.7,7.0 font "Bold-Times-Roman,20" #Same label number causes it to replace.
set yrange [-10:10]
set ytics 5

plot \
tan(x) title 'Tan(x)' ls 3


#unset multiplot #If you'd like to plot multiple files in the same script.