The Sine Gordon Equation

Clear["Global`*"]

The Equation

The equation is

(((∂^2)u)/(∂(x^2))) - (((∂^2)u)/(∂(t^2))) = sin u

sinegordoneq[u_] := D[u[x, t], {x, 2}] - D[u[x, t], {t, 2}] == Sin[u[x, t]] //FullSimplify

Without the right hand side we would have the wave equation with the wave speed, c, set to unity.

One Soliton Solutions

We display a soliton solution; first of all for the special case of no time dependence. We verify that the equation is satisfied by giving the command sinegordoneq and seeing that the result is True.

u[x_, t_] = 4 ArcTan[Exp[x]]; u[x, t] // TraditionalForm

sinegordoneq[u]

From the plot below we see that u varies between 0 (for large negative x) and 2π (for large positive x).

Plot[{u[x,0],2 π},{x,-4,4},PlotRange->{0,6.5},PlotStyle->{{Hue[0],AbsoluteThickness[2]},{Hue[0.7],AbsoluteThickness[2],Dashing[{0.02,0.02}]}}]

A more general solution with time dependence is

u(x, t) = 4 (tan^(-1))[exp[(x - vt )/ (Sqrt[1-(v^2)])] ]

which shows that the soliton travels with velocity v . Note that 1/(Sqrt[1-(v^2)]) is a "Lorentz contraction" factor. We verify again that this satisfies the equation.

u[x_, t_] := 4 ArcTan[Exp[(x - v t)/(Sqrt[1 - (v^2)])]]

sinegordoneq[u]

Now we choose v = 0.8 and produce a simple animation of the soliton. We integrate up to time t = 20, during which the soliton moves a distance x = 16.

v = 0.8;

Animate[ Plot[ u[x, t], {x, -5, 22}, PlotRange -> {0, 6.5} ], {t, 0, 20, 0.25} ]

The "Breather" Solution

There are also multi-soliton solutions, which we don't show, and a "breather" solution, a bound soliton-anti soliton pair, which oscillates and stays close to the origin. Here it is:

ub[x_, t_] =  4ArcTan[ Sin[t/Sqrt[2]]/ Cosh[x/Sqrt[2]]] ; ub[x, t]//TraditionalForm

We verify that it satisfies the sine Gordon equation

sinegordoneq[ub]

and show an animation of it (the period is 2 (Sqrt[2])π). Note that the largest range of u is at x=0 where u varies between -π and π.

Animate [ Plot[ ub[x, t], {x, -6, 6}, PlotRange -> {-3.2, 3.2} ], {t, 0, N[Sqrt[2] 2 Pi], N[Sqrt[2] 2 Pi]/80} ]